Bonjour,

Dans le cadre de mon travail, je reçois tous les jours un certains nombre de reporting excel par mail.

J'aurais aimé savoir s'il y avait un moyen automatique de tranférer les excel reçu par mail directement dans un répertoire réseau (pour baser dessus des requetes Access).

D'avance merci pour votre retour

Bonjour,

Ci-après une macro trouvé sur le web que j'ai adapté et testé.

Macro de Axel C. Lenz

Public Sub saveXLStoDisk(itm As Outlook.MailItem)
Dim dateFormat 'Dateiname mit Datum.
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
dateFormat = Format(Now, "dd_mm_yyyy H-mm") 'Dateiname mit Datum
saveFolder = "C:\temp\"
' XLSs speichern
For Each objAtt In itm.Attachments
If LCase(Right(objAtt.FileName, 4)) = ".xls" Then 'Nach XLS filtern
objAtt.SaveAsFile saveFolder & "\" & dateFormat & "_OL_" & objAtt.DisplayName 'Attachment speichern
Set objAtt = Nothing
End If 'Nach XLS filtern
Next
'Betreff ändern
strID = itm.EntryID
Set objMail = Application.Session.GetItemFromID(strID)
objMail.Subject = "#Classé# " & objMail.Subject
objMail.Save
Set objMail = Nothing
End Sub

Ouvrir l'éditeur VBA dans Outlook : Alt + F11

Insérer le code dans un module : Insertion > Module

Enregistrer et fermer l'éditeur VBA

Il faut adapter le code à vos besoins :

- Changer le répertoire d'enregistrement "C:\temp\"

- Changer si nécessaire la liaison entre la date et le nom du fichier "_OL_" (Objet Liaison)

Nota : la date permet de ne pas écraser un fichier qui aurait le même nom

- Changer si nécessaire le texte qui est ajouté à l'objet du mail "#Classé# (Indique que la/les pièces jointes avec l'extension .xls que vous avez reçus ont été classées dans le répertoire que vous avez désigné)

Ensuite il faut créer une règle sur Outlook :

- Règles et alertes > Nouvelle règle > Vérifier les messages à leur arrivée > Suivant

- Conditions > Sélectionner la coche "Qui contient une pièce jointe" > Suivant

- Actions > Sélectionner la coche "Exécuter un script"

- Dans la fenêtre inférieure > clicker sur "un script" en bleu > un onglet s'ouvre > sélectionner "Projet1.saveXLStoDisk" > OK

- Suivant > Suivant > "Attribuez un nom à cette règle" > Terminer > Appliquer > OK

Tester en vous envoyant à vous même un mail avec un fichier Excel

Cordialement

Bonjour,

Super ça marche nickel. J'ai juste modifié une ligne pour qu'il prenne aussi les fichiers XLSX

If Right(objAtt.FileName, 3) = "xls" Or Right(objAtt.FileName, 4) = "xlsx" Then