tout est dans le titre ou presque^^

je viens ici car je suis deseperé^^

dans un tableau de recap on( car on est plusieurs a se servir du tableau) rentre des valeurs et des dates à partir de relevés qu'on fait avec d'autres logiciels (les relevé ne sont pas lisible par excel)

tout les fichiers des relevés sont rangés par extention dans un dossier

je voudrais que dans le tableur excel , la case du dernier relevé se colore en rouge si il y a un fichier de relevé plus recent dans le dossier (en gros controler que les relevés sont à jour)

pensez vous que ce soit possible a partir de la derniere date de modification

je vous remercie d'avance de votre aide

et je me tient pret à donner d'autre précision car je pense que l'énoncé est un peu brouillon

je tiens a préciser que je travaille sous 2003 sans l'extension de compatibilité pour fichier 2007

apres un petit test de progrmation vb j'obtien:

Private Sub CommandButton1_Click()

Dim ScanFic As Office.FileSearch
Dim NomFic As Variant
Dim Diag As String
Dim Nbr As Long
Dim I As Long

Set ScanFic = Application.FileSearch

With ScanFic
.NewSearch
.LookIn = "c\repertoire"

.SearchSubFolders = True
.FileType = msoFileTypeAllFiles


Nbr = .Execute


I = 0
For Each NomFic In .FoundFiles
I = I + 1
Sheets("Feuil5").Cells(I, 3).Value = NomFic ' adapter le nom de la feuille
Next

MsgBox Diag

End With

End Sub

cela m'affiche la liste des fichiers contenue dans c\repertoire hors je souhaiterais qu'il m'affiche leurs dates de modification et si possible uniquement la derniere

Salut,et bienvenue à toi

tout d'abord, oui ton énoncé est à peine brouillon... , d'ou le peu de réponse à ce jour.

je te conseille de faire un tour par la case départ (te gène pas, c'est le père galopin qui distribue les 20 mille ) pour détailler ton besoin.

ensuite, je ne crois pas qu'on puisse récupérer la date de modif d'un fichier avec le FileSearch ()

dans ton cas je passerai par du FileSystemObject

voir ci-dessous un très bel exemple de P. Erlandsen () à adapter selon ton besoin :

Sub TestListFilesInFolder()
    Workbooks.Add ' create a new workbook for the file list
    ' add headers
    With Range("A1")
        .Formula = "Folder contents:"
        .Font.Bold = True
        .Font.Size = 12
    End With
    Range("A3").Formula = "File Name:"
    Range("B3").Formula = "File Size:"
    Range("C3").Formula = "File Type:"
    Range("D3").Formula = "Date Created:"
    Range("E3").Formula = "Date Last Accessed:"
    Range("F3").Formula = "Date Last Modified:"
    Range("G3").Formula = "Attributes:"
    Range("H3").Formula = "Short File Name:"
    Range("A3:H3").Font.Bold = True
    ListFilesInFolder "C:\FolderName" ' all files in folder
    'ListFilesInFolder "C:\FolderName", "*.*", True ' all files, included subfolders
    'ListFilesInFolder "C:\FolderName", "*.xl*", True ' all Excel files, included subfolders
End Sub

Sub ListFilesInFolder(SourceFolderName As String, Optional FileFilter As String = "*.*", _
    Optional IncludeSubfolders As Boolean = False)
' lists information about the files in SourceFolder
' example: ListFilesInFolder "C:\FolderName", "*.xl*", True
Dim FSO As Scripting.FileSystemObject
Dim SourceFolder As Scripting.Folder, SubFolder As Scripting.Folder
Dim FileItem As Scripting.File, r As Long
    If Len(FileFilter) = 0 Then FileFilter = "*.*"
    Set FSO = New Scripting.FileSystemObject
    On Error Resume Next
    Set SourceFolder = FSO.GetFolder(SourceFolderName)
    On Error GoTo 0
    If Not SourceFolder Is Nothing Then
        r = Range("A65536").End(xlUp).Row
        For Each FileItem In SourceFolder.Files
            If FileItem.Name Like FileFilter Then
                ' display file properties
                r = r + 1 ' next row number
                Cells(r, 1).Formula = FileItem.Path & FileItem.Name
                Cells(r, 2).Formula = FileItem.Size
                Cells(r, 3).Formula = FileItem.Type
                Cells(r, 4).Formula = FileItem.DateCreated
                Cells(r, 5).Formula = FileItem.DateLastAccessed
                Cells(r, 6).Formula = FileItem.DateLastModified
                Cells(r, 7).Formula = FileItem.Attributes
                Cells(r, 8).Formula = FileItem.ShortPath & FileItem.ShortName
                ' use file methods (not proper in this example)
        '        FileItem.Copy "C:\FolderName\Filename.txt", True
        '        FileItem.Move "C:\FolderName\Filename.txt"
        '        FileItem.Delete True
            End If
        Next FileItem
        If IncludeSubfolders Then
            For Each SubFolder In SourceFolder.SubFolders
                ListFilesInFolder SubFolder.Path, True
            Next SubFolder
        End If
        Columns("A:H").AutoFit
        Set FileItem = Nothing
        Set SourceFolder = Nothing
    End If
    Set FSO = Nothing
    ActiveWorkbook.Saved = True
End Sub

tu reviens quand tu veux si tu as besoin d'aide ou de précisions.