Bonjour,

Dans excel, nous avons dans la barre de tache un icone imprimante qui reprend l'imprimante par défaut de XP.

Je voudrai mettre un autre icone à côté et associer celui-ci avec une autre imprimante, comment je peux faire ?

Merci

Bonjour,

De ton explication, je te rappelle qu'il est possible de faire plus simple. Dans la commande "Imprimer" (chemin Fichier\Imprimer), dans le chapitre Imprimante, tu as à disposition une liste déroulante dans laquelle tu sélectionnes le choix de l'imprimante. Au préalable faut-il encore que ton système d'exploitation ait reconnu ton parc.

A +

Oui, mais je voudrai juste deux icones avec chacun l'association d'une imprimante par défaut

A+

Bonjour,

il faut juste enregistrer une macro comme celle ci-dessous. Ensuite ajouter un bouton à tes barres d'outils en lui attribuant la macro.

_______________________________________

Sub imprim()
'
' imprim Macro
' Macro enregistrée le 11/07/2008 par ToTo
'

'
Application.ActivePrinter = "Microsoft XPS Document Writer sur Ne02:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:= _
"Microsoft XPS Document Writer sur Ne02:", Collate:=True
Application.ActivePrinter = "PDFCreator sur Ne00:"
End Sub

__________________________________

A toi de mettre les noms d'imprimantes:

Microsoft XPS Document Writer sur Ne02 à la place l'imprimante ponctuelle

PDFCreator sur Ne00 à la place l'imprimante par défaut.

Voilà...

A+

D D DU 06

RE,

J'entends bien ! je t'ai indiqué une procédure d'école.

Tu peux aussi glisser un racourci de chacune des imprimantes dans ta barre des tâches mais ce n'est pas une procédure référencée.

Chemin : Panneau Config\Imprimantes et Télécopies\clic droit - Créer un raccourci\dévérouiller barre tâches\Glisser raccourci\vérouiller barre tâches.

Merci pour vos réponses, je regarde tout ça demain et je vous tiens au courant.

Bonne soirée

Salut

une petite adaptation personnelle : http://cjoint.com/?hlrRkad7Pa

(d'après une idée originale de Môssieur L Longre)

enjoy...

[EDIT : attention, ça imprime directement... ; je ferai une nvlle version ce soir si j'ai le tps]

bon, j'ai bien mangé j'ai bien bu, et j'ai pas sommeil

le cjoint ci dessus n'est pas finalisé, je vous le conseille pas...

j'ai retouché un peu la bestiole en chiadant un peu (pour le sport) :

c'est devnu une xla qui insère un nouveau control (liste déroulante de toutes les imprimantes dispo) dans la barre d'outil standard

en choisissant une imprimante, on lance directement l'impression...

je vous balance la gaterie façon Galopin (à la tienne ) : clic!

et en cadeau bonus, puisque le lien ne restera pas, je vous donne le code (à coller dans un module standard) :

' sur la base d'une idée originale signée Laurent LONGRE
' les déclarations proviennent de lui sauf la dernière

Private Declare Function EnumPrintersA Lib "Winspool.drv" _
(ByVal flags As Long, ByVal name As String, ByVal Level As Long, _
pPrinterEnum As Long, ByVal cdBuf As Long, pcbNeeded As Long, _
pcReturned As Long) As Long

Private Declare Sub RtlMoveMemory Lib "Kernel32" (pDest As Long, _
ByVal pSource As Long, ByVal Length As Long)

Private Declare Function lstrlenA Lib "Kernel32" _
(ByVal lpString As Any) As Long

Private Declare Function lstrcpyA Lib "Kernel32" _
(ByVal lpString1 As String, ByVal lpString2 As Long) As Long

Dim idx%

Sub auto_open()

Dim nouvMenu As CommandBarComboBox
Set nouvMenu = Application.CommandBars(3).Controls.Add(Type:=msoControlComboBox, temporary:=True)

'début du code original
Dim PrinterEnum() As Long, Impr As String
Dim Needed As Long, Returned As Long, i As Integer
Dim Res As Long
EnumPrintersA 2, vbNullString, 2, 0, 0, Needed, 0
If Needed = 0 Then MsgBox "Erreur", vbCritical: Exit Sub
ReDim PrinterEnum(Needed / 4)
If EnumPrintersA(2, vbNullString, 2, PrinterEnum(0), Needed, _
Needed, Returned) = 0 Then MsgBox "Erreur", vbCritical: Exit Sub
For i = 1 To Returned * 21 Step 21
Impr = Space$(lstrlenA(PrinterEnum(i)))
lstrcpyA Impr, PrinterEnum(i)
If PrinterEnum(i + 6) Then _
RtlMoveMemory Res, PrinterEnum(i + 6) + 58, 2
'légère modif ci-dessous
'MsgBox "Imprimante : " & Impr & vbCr & vbCr & "Résolution : " _
& IIf(PrinterEnum(I + 6), Res, "Inconnue")
nouvMenu.AddItem Impr
Next i
'fin du code original ; prévu pour donner également la résolution d'impression
With nouvMenu
.OnAction = "imprime"
.Text = "Choisissez une imprimante"
.Width = 155
.DropDownWidth = -1
idx = .Index
End With
End Sub

Sub imprime()
On Error GoTo compteur
Dim i%, j%
ActivePrinter = Application.CommandBars(3).Controls(idx).List(Application.CommandBars(3).Controls(idx).ListIndex) & " sur Ne" & i & j & ":"
ActiveWorkbook.Windows(1).SelectedSheets.PrintOut
Exit Sub
compteur:
If j = 9 Then
i = i + 1: j = 0
Else
j = j + 1
End If
If i = 100 Then Exit Sub
Resume
End Sub

Bonjour,

Je me permet de relancer mon sujet car je n'ai pas résolu mon problème.

Lorsque je fais ce que D D DU 06 me dit j'ai une erreur 400 qui s'affiche.

Pouvez vous m'aider.

Merci